echo on
*
* Remove old versions of files that will be re-created later...
*
sc rm tmp_*  *_tmp.?
*
* Remove the previous P- and S-wave markers and substitute it with a theoretical one... Then write out a new file
*
* At the same time, check the local magnitude given by FVGSN and hipass filter waveforms accordingly...
*
do file wild *.HHZ
 message 'file:  $file '
 setbb statname (BEFORE ".HHZ" $file )
 r %statname%.HHN 
 ch cmpinc 90 ; ch cmpaz 0
 wh over
 r %statname%.HHE 
 ch cmpinc 90 ; ch cmpaz 90
 wh over
 r %statname%.HHN %statname%.HHE %statname%.HHZ
 rtr
 rmean
 ch lcalda true
 ch lovrok true
 sc rm ttimes.in ttimes.out gcarc.out depth.out stimes.out stime.out
 TRANSCRIPT CREATE FILE gcarc.out CONTENTS OUTPUT
 message " &1,gcarc "
 TRANSCRIPT CLOSE
 TRANSCRIPT CREATE FILE depth.out CONTENTS OUTPUT
 message " &1,evdp "
 TRANSCRIPT CLOSE
 TRANSCRIPT CREATE FILE statname.out CONTENTS OUTPUT
 message " %statname% "
 TRANSCRIPT CLOSE
 w %statname%_tmp.r %statname%_tmp.t %statname%_tmp.z
 sc sh /data/27/luca/Ground_Motion_Bay_Area/Data/comp_times_new.sh %statname%_tmp
*
* Now make sure that the h-comp. have the same number of points...
*
 r %statname%_tmp.r %statname%_tmp.t
 ch lcalda true
 ch lovrok true
 synch
 wh over
*
 setbb c0 &1,b
*
 if &2,b gt %c0 then
 setbb c0 &2,b
 endif
*
 setbb c1 &1,e
*
 if &2,e lt %c1 then
 setbb c1 &2,e
 endif
*
 cut %c0 %c1
 r %statname%_tmp.r %statname%_tmp.t
 cut off
 synch
*
* Now rotate h-comps....
*	
 rotate to gcp
 w over
enddo